shell/common/BUILD.gn

# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# Template to generate a dart embedder resource.cc file.
# Required invoker inputs:
#   String output (name of output file)
#   List inputs (list of input files to be included)
#   String table_name (name of symbol for resource table)
#   String root_prefix (base directory of resources)
# Optional invoker inputs:
#   String input_directory (directory of resources that are recursively added)
#   List deps
#   List datadeps
template("dart_embedder_resources") {
  action(target_name) {
    script = "//dart/runtime/tools/create_resources.py"
    deps = []
    if (defined(invoker.deps)) {
      deps += invoker.deps
    }
    datadeps = []
    if (defined(invoker.datadeps)) {
      datadeps = invoker.datadeps
    }

    output = invoker.output
    outputs = [
      output,
    ]

    inputs = [ script ] + invoker.inputs

    root_prefix = rebase_path(invoker.root_prefix)

    args = [
      "--output",
      rebase_path(output),
      "--outer_namespace",
      "flutter",
      "--inner_namespace",
      "runtime",
      "--table_name",
      invoker.table_name,
      "--root_prefix",
      root_prefix,
    ]
    if (defined(invoker.input_directory)) {
      args += [
        "--client_root",
        rebase_path(invoker.input_directory),
      ]
    }
    args += rebase_path(invoker.inputs)
  }
}

dart_embedder_resources("generate_embedder_diagnostic_server_resources_cc") {
  inputs = [
    "//flutter/shell/common/diagnostic/diagnostic_server.dart",
  ]
  root_prefix = "//flutter/shell/common/diagnostic/"
  output = "$target_gen_dir/embedder_diagnostic_server_resources.cc"
  table_name = "sky_embedder_diagnostic_server"
}

source_set("common") {
  sources = [
    "$target_gen_dir/embedder_diagnostic_server_resources.cc",
    "animator.cc",
    "animator.h",
    "diagnostic/diagnostic_server.cc",
    "diagnostic/diagnostic_server.h",
    "engine.cc",
    "engine.h",
    "null_rasterizer.cc",
    "null_rasterizer.h",
    "picture_serializer.cc",
    "picture_serializer.h",
    "platform_view.cc",
    "platform_view.h",
    "platform_view_service_protocol.cc",
    "platform_view_service_protocol.h",
    "rasterizer.cc",
    "rasterizer.h",
    "shell.cc",
    "shell.h",
    "skia_event_tracer_impl.cc",
    "skia_event_tracer_impl.h",
    "surface.cc",
    "surface.h",
    "switches.cc",
    "switches.h",
    "tracing_controller.cc",
    "tracing_controller.h",
    "vsync_waiter.cc",
    "vsync_waiter.h",
    "vsync_waiter_fallback.cc",
    "vsync_waiter_fallback.h",
  ]

  deps = [
    ":generate_embedder_diagnostic_server_resources_cc",
    "//dart/runtime:dart_api",
    "//dart/runtime/vm:libdart_platform",
    "//flutter/assets",
    "//flutter/common",
    "//flutter/flow",
    "//flutter/fml",
    "//flutter/glue",
    "//flutter/lib/ui",
    "//flutter/runtime",
    "//flutter/sky/engine/wtf",
    "//flutter/synchronization",
    "//lib/ftl",
    "//lib/tonic",
    "//third_party/rapidjson",
    "//third_party/skia",
    "//third_party/skia:gpu",
  ]
}