shell/platform/darwin/BUILD.gn

# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(is_mac || is_ios)

group("darwin") {
  if (is_mac) {
    deps = [
      "desktop:shell_standalone",
    ]
    if (!is_fuchsia_host) {
      deps += [
        "desktop:shell_application_bundle",
      ]
    }
  } else if (is_ios) {
    deps = [
      "ios:flutter_framework",
    ]
  } else {
    assert(false, "Unknown darwin platform type.")
  }
}

source_set("flutter_channels") {
  set_sources_assignment_filter([])
  sources = [
    "common/buffer_conversions.h",
    "common/buffer_conversions.mm",
    "ios/framework/Headers/FlutterBinaryMessenger.h",
    "ios/framework/Headers/FlutterChannels.h",
    "ios/framework/Headers/FlutterCodecs.h",
    "ios/framework/Source/FlutterChannels.mm",
    "ios/framework/Source/FlutterCodecs.mm",
    "ios/framework/Source/FlutterStandardCodec.mm",
    "ios/framework/Source/FlutterStandardCodec_Internal.h",
  ]
  set_sources_assignment_filter(sources_assignment_filter)

  deps = [
    "//flutter/common",
    "//flutter/flow",
    "//flutter/fml",
    "//flutter/runtime",
    "//flutter/shell/common",
    "//flutter/shell/gpu",
    "//flutter/shell/testing",
    "//flutter/sky/engine/wtf",
    "//lib/ftl",
    "//third_party/skia",
  ]
}

executable("flutter_channels_unittests") {
  testonly = true

  set_sources_assignment_filter([])
  sources = [
    "ios/framework/Source/flutter_codecs_unittest.mm",
    "ios/framework/Source/flutter_standard_codec_unittest.mm",
  ]
  set_sources_assignment_filter(sources_assignment_filter)

  deps = [
    ":flutter_channels",
    "//dart/runtime:libdart_jit",
    "//flutter/testing",
  ]
}