services/dynamic/BUILD.gn

# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("embedder") {
  sources = [
    "dynamic_service.c",
    "dynamic_service.h",
    "dynamic_service_definition.cc",
    "dynamic_service_definition.h",
    "dynamic_service_embedder.c",
    "dynamic_service_embedder.h",
    "dynamic_service_macros.h",
  ]

  deps = [
    "//mojo/public/c/environment",
    "//mojo/public/c/system",
  ]

  # In order for the embedder to access the routine that prepares the
  # the thunk for dylib, It needs access to system_thunks.h. This is included
  # in a target that includes mojo symbols already present on the embedder.
  # This works around header checks just for these files.
  check_includes = false

  defines = [
    "DYNAMIC_SERVICE_EMBEDDER",
  ]
}

lib_sources = [
  "dynamic_service.c",
  "dynamic_service.h",
  "dynamic_service_dylib.cc",
  "dynamic_service_dylib.h",
  "dynamic_service_macros.h",
]

lib_deps = [
  "//mojo/public/c/system",
  "//mojo/public/cpp/bindings",
  "//mojo/public/cpp/environment:standalone",
  "//mojo/public/platform/native:system",
]

static_library("sdk_lib_archive") {
  complete_static_lib = true
  output_name = "FlutterService"
  sources = lib_sources
  deps = lib_deps
}

source_set("sdk_lib") {
  sources = lib_sources
  deps = lib_deps
}