build/toolchain/mac/BUILD.gn - mirrors/engine - Git at Google

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.

 # TODO(brettw) Use "gcc_toolchain.gni" like the Linux toolchains. This requires
 # some enhancements since the commands on Mac are slightly different than on
 # Linux.

 import("../goma.gni")
 import("//build/config/ios/ios_sdk.gni")

 assert(host_os == "mac")

 import("//build/toolchain/clang.gni")
 import("//build/toolchain/goma.gni")
 import("//build/config/sysroot.gni")

 if (use_goma) {
   goma_prefix = "$goma_dir/gomacc "
 } else {
   goma_prefix = ""
 }

 # This will copy the gyp-mac-tool to the build directory. We pass in the source
 # file of the win tool.
 gyp_mac_tool_source =
     rebase_path("//tools/gyp/pylib/gyp/mac_tool.py", root_build_dir)
 exec_script("setup_toolchain.py", [ gyp_mac_tool_source ])

 # Shared toolchain definition. Invocations should set toolchain_os to set the
 # build args in this definition.
 template("mac_toolchain") {
   toolchain(target_name) {
     assert(defined(invoker.cc), "mac_toolchain() must specify a \"cc\" value")
     assert(defined(invoker.cxx), "mac_toolchain() must specify a \"cxx\" value")
     assert(defined(invoker.ld), "mac_toolchain() must specify a \"ld\" value")
     assert(defined(invoker.toolchain_cpu),
            "mac_toolchain() must specify a \"toolchain_cpu\"")
     assert(defined(invoker.toolchain_os),
            "mac_toolchain() must specify a \"toolchain_os\"")
     assert(defined(invoker.switch_sysroot),
            "mac_toolchain() must specify a \"switch_sysroot\"")

     # We can't do string interpolation ($ in strings) on things with dots in
     # them. To allow us to use $cc below, for example, we create copies of
     # these values in our scope.
     cc = invoker.cc
     cxx = invoker.cxx
     ld = invoker.ld

     # Make these apply to all tools below.
     lib_switch = "-l"
     lib_dir_switch = "-L"

     sysroot_flags = ""

     if (invoker.switch_sysroot) {
       version_flags = ""

       if (use_ios_simulator) {
         version_flags = "-mios-simulator-version-min=$ios_deployment_target"
       } else {
         version_flags = "-miphoneos-version-min=$ios_deployment_target"
       }

       sysroot_flags = "-isysroot $sysroot $version_flags"
     }

     tool("cc") {
       depfile = "{{output}}.d"
       command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "CC {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
       ]
     }

     tool("cxx") {
       depfile = "{{output}}.d"
       command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "CXX {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
       ]
     }

     tool("asm") {
       # For GCC we can just use the C compiler to compile assembly.
       depfile = "{{output}}.d"
       command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "ASM {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
       ]
     }

     tool("objc") {
       depfile = "{{output}}.d"
       command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_c}} {{cflags_objc}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "OBJC {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
       ]
     }

     tool("objcxx") {
       depfile = "{{output}}.d"
       command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_cc}} {{cflags_objcc}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "OBJCXX {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
       ]
     }

     tool("alink") {
       command = "rm -f {{output}} && ./gyp-mac-tool filter-libtool libtool -static -o {{output}} {{inputs}}"
       description = "LIBTOOL-STATIC {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}{{output_extension}}",
       ]
       default_output_extension = ".a"
       output_prefix = "lib"
     }

     tool("solink") {
       dylib = "{{root_out_dir}}/{{target_output_name}}{{output_extension}}"  # eg "./libfoo.dylib"
       rspfile = dylib + ".rsp"

       # These variables are not build into GN but are helpers that implement
       # (1) linking to produce a .so, (2) extracting the symbols from that file
       # to a temporary file, (3) if the temporary file has differences from the
       # existing .TOC file, overwrite it, oterwise, don't change it.
       #
       # As a special case, if the library reexports symbols from other dynamic
       # libraries, we always update the .TOC and skip the temporary file and
       # diffing steps, since that library always needs to be re-linked.
       tocname = dylib + ".TOC"
       temporary_tocname = dylib + ".tmp"

       does_reexport_command = "[ ! -e $dylib -o ! -e $tocname ] || otool -l $dylib | grep -q LC_REEXPORT_DYLIB"
       link_command = "$ld -shared $sysroot_flags {{ldflags}} -o $dylib -Wl,-filelist,$rspfile {{solibs}} {{libs}}"
       replace_command = "if ! cmp -s $temporary_tocname $tocname; then mv $temporary_tocname $tocname"
       extract_toc_command = "{ otool -l $dylib | grep LC_ID_DYLIB -A 5; nm -gP $dylib | cut -f1-2 -d' ' | grep -v U\$\$; true; }"

       command = "if $does_reexport_command ; then $link_command && $extract_toc_command > $tocname; else $link_command && $extract_toc_command > $temporary_tocname && $replace_command ; fi; fi"

       rspfile_content = "{{inputs_newline}}"

       description = "SOLINK {{output}}"

       # Use this for {{output_extension}} expansions unless a target manually
       # overrides it (in which case {{output_extension}} will be what the target
       # specifies).
       default_output_extension = ".dylib"

       output_prefix = "lib"

       # Since the above commands only updates the .TOC file when it changes, ask
       # Ninja to check if the timestamp actually changed to know if downstream
       # dependencies should be recompiled.
       restat = true

       # Tell GN about the output files. It will link to the dylib but use the
       # tocname for dependency management.
       outputs = [
         dylib,
         tocname,
       ]
       link_output = dylib
       depend_output = tocname
     }

     tool("link") {
       outfile = "{{root_out_dir}}/{{target_output_name}}{{output_extension}}"
       rspfile = "$outfile.rsp"
       command = "$ld $sysroot_flags {{ldflags}} -o $outfile -Wl,-filelist,$rspfile {{solibs}} {{libs}}"
       description = "LINK $outfile"
       rspfile_content = "{{inputs_newline}}"
       outputs = [
         outfile,
       ]
     }

     tool("stamp") {
       command = "touch {{output}}"
       description = "STAMP {{output}}"
     }

     tool("copy") {
       command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
       description = "COPY {{source}} {{output}}"
     }

     toolchain_args() {
       current_cpu = invoker.toolchain_cpu
       current_os = invoker.toolchain_os

       # These values need to be passed through unchanged.
       target_os = target_os
       target_cpu = target_cpu

       if (defined(invoker.is_clang)) {
         is_clang = invoker.is_clang
       }
     }
   }
 }

 mac_toolchain("clang_arm") {
   toolchain_cpu = "arm"
   toolchain_os = "mac"
   prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
                        root_build_dir)
   cc = "${goma_prefix}$prefix/clang"
   cxx = "${goma_prefix}$prefix/clang++"
   ld = cxx
   is_clang = true
   switch_sysroot = false
 }

 mac_toolchain("ios_clang_arm") {
   toolchain_cpu = "arm"
   toolchain_os = "mac"
   prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
                        root_build_dir)
   cc = "${goma_prefix}$prefix/clang"
   cxx = "${goma_prefix}$prefix/clang++"
   ld = cxx
   is_clang = true
   switch_sysroot = true
 }

 mac_toolchain("arm") {
   toolchain_cpu = "arm"
   toolchain_os = "mac"
   cc = "${goma_prefix}/gcc"
   cxx = "${goma_prefix}/g++"
   ld = cxx
   is_clang = false
   switch_sysroot = false
 }

 mac_toolchain("clang_x64") {
   toolchain_cpu = "x64"
   toolchain_os = "mac"
   prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
                        root_build_dir)
   cc = "${goma_prefix}$prefix/clang"
   cxx = "${goma_prefix}$prefix/clang++"
   ld = cxx
   is_clang = true
   switch_sysroot = false
 }

 mac_toolchain("x64") {
   toolchain_cpu = "x64"
   toolchain_os = "mac"
   cc = "${goma_prefix}/gcc"
   cxx = "${goma_prefix}/g++"
   ld = cxx
   is_clang = false
   switch_sysroot = false
 }
	# Copyright (c) 2013 The Chromium Authors. All rights reserved.
	# Use of this source code is governed by a BSD-style license that can be
	# found in the LICENSE file.

	# TODO(brettw) Use "gcc_toolchain.gni" like the Linux toolchains. This requires
	# some enhancements since the commands on Mac are slightly different than on
	# Linux.

	import("../goma.gni")
	import("//build/config/ios/ios_sdk.gni")

	assert(host_os == "mac")

	import("//build/toolchain/clang.gni")
	import("//build/toolchain/goma.gni")
	import("//build/config/sysroot.gni")

	if (use_goma) {
	goma_prefix = "$goma_dir/gomacc "
	} else {
	goma_prefix = ""
	}

	# This will copy the gyp-mac-tool to the build directory. We pass in the source
	# file of the win tool.
	gyp_mac_tool_source =
	rebase_path("//tools/gyp/pylib/gyp/mac_tool.py", root_build_dir)
	exec_script("setup_toolchain.py", [ gyp_mac_tool_source ])

	# Shared toolchain definition. Invocations should set toolchain_os to set the
	# build args in this definition.
	template("mac_toolchain") {
	toolchain(target_name) {
	assert(defined(invoker.cc), "mac_toolchain() must specify a \"cc\" value")
	assert(defined(invoker.cxx), "mac_toolchain() must specify a \"cxx\" value")
	assert(defined(invoker.ld), "mac_toolchain() must specify a \"ld\" value")
	assert(defined(invoker.toolchain_cpu),
	"mac_toolchain() must specify a \"toolchain_cpu\"")
	assert(defined(invoker.toolchain_os),
	"mac_toolchain() must specify a \"toolchain_os\"")
	assert(defined(invoker.switch_sysroot),
	"mac_toolchain() must specify a \"switch_sysroot\"")

	# We can't do string interpolation ($ in strings) on things with dots in
	# them. To allow us to use $cc below, for example, we create copies of
	# these values in our scope.
	cc = invoker.cc
	cxx = invoker.cxx
	ld = invoker.ld

	# Make these apply to all tools below.
	lib_switch = "-l"
	lib_dir_switch = "-L"

	sysroot_flags = ""

	if (invoker.switch_sysroot) {
	version_flags = ""

	if (use_ios_simulator) {
	version_flags = "-mios-simulator-version-min=$ios_deployment_target"
	} else {
	version_flags = "-miphoneos-version-min=$ios_deployment_target"
	}

	sysroot_flags = "-isysroot $sysroot $version_flags"
	}

	tool("cc") {
	depfile = "{{output}}.d"
	command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
	depsformat = "gcc"
	description = "CC {{output}}"
	outputs = [
	"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
	]
	}

	tool("cxx") {
	depfile = "{{output}}.d"
	command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
	depsformat = "gcc"
	description = "CXX {{output}}"
	outputs = [
	"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
	]
	}

	tool("asm") {
	# For GCC we can just use the C compiler to compile assembly.
	depfile = "{{output}}.d"
	command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
	depsformat = "gcc"
	description = "ASM {{output}}"
	outputs = [
	"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
	]
	}

	tool("objc") {
	depfile = "{{output}}.d"
	command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_c}} {{cflags_objc}} -c {{source}} -o {{output}}"
	depsformat = "gcc"
	description = "OBJC {{output}}"
	outputs = [
	"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
	]
	}

	tool("objcxx") {
	depfile = "{{output}}.d"
	command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} $sysroot_flags {{cflags}} {{cflags_cc}} {{cflags_objcc}} -c {{source}} -o {{output}}"
	depsformat = "gcc"
	description = "OBJCXX {{output}}"
	outputs = [
	"{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
	]
	}

	tool("alink") {
	command = "rm -f {{output}} && ./gyp-mac-tool filter-libtool libtool -static -o {{output}} {{inputs}}"
	description = "LIBTOOL-STATIC {{output}}"
	outputs = [
	"{{target_out_dir}}/{{target_output_name}}{{output_extension}}",
	]
	default_output_extension = ".a"
	output_prefix = "lib"
	}

	tool("solink") {
	dylib = "{{root_out_dir}}/{{target_output_name}}{{output_extension}}" # eg "./libfoo.dylib"
	rspfile = dylib + ".rsp"

	# These variables are not build into GN but are helpers that implement
	# (1) linking to produce a .so, (2) extracting the symbols from that file
	# to a temporary file, (3) if the temporary file has differences from the
	# existing .TOC file, overwrite it, oterwise, don't change it.
	#
	# As a special case, if the library reexports symbols from other dynamic
	# libraries, we always update the .TOC and skip the temporary file and
	# diffing steps, since that library always needs to be re-linked.
	tocname = dylib + ".TOC"
	temporary_tocname = dylib + ".tmp"

	does_reexport_command = "[ ! -e $dylib -o ! -e $tocname ] \|\| otool -l $dylib \| grep -q LC_REEXPORT_DYLIB"
	link_command = "$ld -shared $sysroot_flags {{ldflags}} -o $dylib -Wl,-filelist,$rspfile {{solibs}} {{libs}}"
	replace_command = "if ! cmp -s $temporary_tocname $tocname; then mv $temporary_tocname $tocname"
	extract_toc_command = "{ otool -l $dylib \| grep LC_ID_DYLIB -A 5; nm -gP $dylib \| cut -f1-2 -d' ' \| grep -v U\$\$; true; }"

	command = "if $does_reexport_command ; then $link_command && $extract_toc_command > $tocname; else $link_command && $extract_toc_command > $temporary_tocname && $replace_command ; fi; fi"

	rspfile_content = "{{inputs_newline}}"

	description = "SOLINK {{output}}"

	# Use this for {{output_extension}} expansions unless a target manually
	# overrides it (in which case {{output_extension}} will be what the target
	# specifies).
	default_output_extension = ".dylib"

	output_prefix = "lib"

	# Since the above commands only updates the .TOC file when it changes, ask
	# Ninja to check if the timestamp actually changed to know if downstream
	# dependencies should be recompiled.
	restat = true

	# Tell GN about the output files. It will link to the dylib but use the
	# tocname for dependency management.
	outputs = [
	dylib,
	tocname,
	]
	link_output = dylib
	depend_output = tocname
	}

	tool("link") {
	outfile = "{{root_out_dir}}/{{target_output_name}}{{output_extension}}"
	rspfile = "$outfile.rsp"
	command = "$ld $sysroot_flags {{ldflags}} -o $outfile -Wl,-filelist,$rspfile {{solibs}} {{libs}}"
	description = "LINK $outfile"
	rspfile_content = "{{inputs_newline}}"
	outputs = [
	outfile,
	]
	}

	tool("stamp") {
	command = "touch {{output}}"
	description = "STAMP {{output}}"
	}

	tool("copy") {
	command = "ln -f {{source}} {{output}} 2>/dev/null \|\| (rm -rf {{output}} && cp -af {{source}} {{output}})"
	description = "COPY {{source}} {{output}}"
	}

	toolchain_args() {
	current_cpu = invoker.toolchain_cpu
	current_os = invoker.toolchain_os

	# These values need to be passed through unchanged.
	target_os = target_os
	target_cpu = target_cpu

	if (defined(invoker.is_clang)) {
	is_clang = invoker.is_clang
	}
	}
	}
	}

	mac_toolchain("clang_arm") {
	toolchain_cpu = "arm"
	toolchain_os = "mac"
	prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
	root_build_dir)
	cc = "${goma_prefix}$prefix/clang"
	cxx = "${goma_prefix}$prefix/clang++"
	ld = cxx
	is_clang = true
	switch_sysroot = false
	}

	mac_toolchain("ios_clang_arm") {
	toolchain_cpu = "arm"
	toolchain_os = "mac"
	prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
	root_build_dir)
	cc = "${goma_prefix}$prefix/clang"
	cxx = "${goma_prefix}$prefix/clang++"
	ld = cxx
	is_clang = true
	switch_sysroot = true
	}

	mac_toolchain("arm") {
	toolchain_cpu = "arm"
	toolchain_os = "mac"
	cc = "${goma_prefix}/gcc"
	cxx = "${goma_prefix}/g++"
	ld = cxx
	is_clang = false
	switch_sysroot = false
	}

	mac_toolchain("clang_x64") {
	toolchain_cpu = "x64"
	toolchain_os = "mac"
	prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
	root_build_dir)
	cc = "${goma_prefix}$prefix/clang"
	cxx = "${goma_prefix}$prefix/clang++"
	ld = cxx
	is_clang = true
	switch_sysroot = false
	}

	mac_toolchain("x64") {
	toolchain_cpu = "x64"
	toolchain_os = "mac"
	cc = "${goma_prefix}/gcc"
	cxx = "${goma_prefix}/g++"
	ld = cxx
	is_clang = false
	switch_sysroot = false
	}