blob: b5fda38018087650af44a232834b61d4b3a7b5ae [file] [log] [blame]
import("//flutter/build/zip_bundle.gni")
zip_bundle("artifacts") {
output = "$host_os-$target_cpu/artifacts.zip"
deps = [
"//flutter/flutter_frontend_server:frontend_server",
"//flutter/lib/snapshot:generate_snapshot_bin",
"//flutter/shell/testing:testing",
]
files = [
{
source = "//third_party/icu/flutter/icudtl.dat"
destination = "icudtl.dat"
},
{
source = "$root_out_dir/gen/flutter/lib/snapshot/isolate_snapshot.bin"
destination = "isolate_snapshot.bin"
},
{
source = "$root_gen_dir/flutter/lib/snapshot/vm_isolate_snapshot.bin"
destination = "vm_isolate_snapshot.bin"
},
{
source = "$root_gen_dir/frontend_server.dart.snapshot"
destination = "frontend_server.dart.snapshot"
},
]
if (host_os == "win") {
files += [
{
source = "$root_out_dir/flutter_tester.exe"
destination = "flutter_tester"
},
]
} else {
files += [
{
source = "$root_out_dir/flutter_tester"
destination = "flutter_tester"
},
]
}
}
if (host_os == "linux") {
group("linux-embedder") {
deps = [ "//flutter/shell/platform/embedder:linux-embedder-archive" ]
}
}
# Generates flutter_patched_sdk.zip for debug and profile runtime modes
# and saves it in the zips_archive folder. For release runtime mode it
# generates flutter_patched_sdk_product.zip and saves it to
# zips_archive/flutter_patched_sdk_product/ folder.
zip_bundle("flutter_patched_sdk") {
file_suffix = ""
path_prefix = ""
if (flutter_runtime_mode == "release") {
file_suffix = "_product"
path_prefix = "flutter_patched_sdk_product/"
}
output = "flutter_patched_sdk${file_suffix}.zip"
deps = [ "//flutter/lib/snapshot:strong_platform" ]
files = [
{
source = "$root_out_dir/flutter_patched_sdk/vm_outline_strong.dill"
destination = "${path_prefix}vm_outline_strong.dill"
},
{
source = "$root_out_dir/flutter_patched_sdk/platform_strong.dill"
destination = "${path_prefix}platform_strong.dill"
},
]
}
# Flutter consumes the dart sdk as a prebuilt. Rather than regenerating
# the zip file we are just copying the original file to the artifacts location.
if (build_engine_artifacts && flutter_prebuilt_dart_sdk) {
copy("dart_sdk_archive") {
sources = [ prebuilt_dart_sdk_archive ]
outputs =
[ "$root_out_dir/zip_archives/dart-sdk-$prebuilt_dart_sdk_config" ]
}
}