| dnl These m4 macros are whitespace sensitive and break if moved around much. |
| m4_define([LU_VERSION_H], m4_include([libusb/version.h])) |
| m4_define([LU_DEFINE_VERSION_ATOM], |
| [m4_define([$1], m4_bregexp(LU_VERSION_H, |
| [^#define\s*$1\s*\([0-9]*\).*], [\1]))]) |
| m4_define([LU_DEFINE_VERSION_RC_ATOM], |
| [m4_define([$1], m4_bregexp(LU_VERSION_H, |
| [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))]) |
| dnl The m4_bregexp() returns (only) the numbers following the #define named |
| dnl in the first macro parameter. m4_define() then defines the name for use |
| dnl in AC_INIT. |
| |
| LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR]) |
| LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR]) |
| LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO]) |
| LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC]) |
| |
| AC_PREREQ([2.69]) |
| AC_INIT([libusb-1.0], [LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC], [libusb-devel@lists.sourceforge.net], [libusb-1.0], [http://libusb.info]) |
| AC_CONFIG_HEADERS([config.h]) |
| AC_CONFIG_SRCDIR([libusb/core.c]) |
| AC_CONFIG_MACRO_DIR([m4]) |
| AC_PROG_CC |
| AC_PROG_CXX |
| AC_C_INLINE |
| AM_INIT_AUTOMAKE |
| LT_INIT |
| LT_LANG([Windows Resource]) |
| |
| dnl Library versioning |
| dnl These numbers should be tweaked on every release. Read carefully: |
| dnl http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html |
| dnl http://sourceware.org/autobook/autobook/autobook_91.html |
| lt_current=2 |
| lt_revision=0 |
| lt_age=2 |
| LT_LDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age} -no-undefined" |
| |
| m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])]) |
| |
| dnl check for -std=gnu11 compiler support (optional) |
| dnl note that we don't just check whether the compiler accepts '-std=x11' |
| dnl but also that it supports the _Thread_local keyword because some compilers |
| dnl (e.g. gcc 4.8) accept the command line option but do not implement TLS |
| saved_CFLAGS="${CFLAGS}" |
| CFLAGS="-std=gnu11" |
| AC_MSG_CHECKING([whether CC supports -std=gnu11]) |
| AC_COMPILE_IFELSE([AC_LANG_PROGRAM([_Thread_local int x;], [x = 42;])], |
| [AC_MSG_RESULT([yes]) |
| cc_supports_gnu11=yes], |
| [AC_MSG_RESULT([no]) |
| cc_supports_gnu11=]) |
| CFLAGS="${saved_CFLAGS}" |
| |
| if test "x$cc_supports_gnu11" = xyes; then |
| AM_CFLAGS="-std=gnu11" |
| else |
| dnl fallback check for -std=c11 compiler support (required) |
| saved_CFLAGS="${CFLAGS}" |
| CFLAGS="-std=c11" |
| AC_MSG_CHECKING([whether CC supports -std=c11]) |
| AC_COMPILE_IFELSE([AC_LANG_PROGRAM([_Thread_local int x;], [x = 42;])], |
| [AC_MSG_RESULT([yes])], |
| [AC_MSG_RESULT([no]) |
| AC_MSG_ERROR([compiler with C11 support is required to build libusb])]) |
| CFLAGS="${saved_CFLAGS}" |
| AM_CFLAGS="-std=c11" |
| fi |
| |
| AC_DEFINE([_GNU_SOURCE], [1], [Enable GNU extensions.]) |
| AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__ ((visibility ("default")))], [Define to the attribute for default visibility.]) |
| |
| create_import_lib= |
| is_android_linux= |
| AC_MSG_CHECKING([operating system]) |
| case $host in |
| *-darwin*) |
| AC_MSG_RESULT([Darwin/Mac OS X]) |
| backend=darwin |
| poll=posix |
| threads=posix |
| ;; |
| *-haiku*) |
| AC_MSG_RESULT([Haiku]) |
| backend=haiku |
| poll=posix |
| threads=posix |
| ;; |
| *-linux* | *-uclinux*) |
| dnl on Android Linux, some functions are in different places |
| case $host in |
| *-linux-android*) |
| AC_MSG_RESULT([Android Linux]) |
| is_android_linux=yes |
| ;; |
| *) |
| AC_MSG_RESULT([Linux]) |
| ;; |
| esac |
| backend=linux |
| poll=posix |
| threads=posix |
| ;; |
| *-netbsd*) |
| AC_MSG_RESULT([NetBSD]) |
| backend=netbsd |
| poll=posix |
| threads=posix |
| ;; |
| *-openbsd*) |
| AC_MSG_RESULT([OpenBSD]) |
| backend=openbsd |
| poll=posix |
| threads=posix |
| ;; |
| *-solaris*) |
| AC_MSG_RESULT([SunOS]) |
| backend=sunos |
| poll=posix |
| threads=posix |
| ;; |
| *-cygwin*) |
| AC_MSG_RESULT([Windows (using Cygwin)]) |
| backend=windows |
| poll=windows |
| threads=posix |
| ;; |
| *-mingw* | *msys*) |
| AC_MSG_RESULT([Windows]) |
| backend=windows |
| poll=windows |
| threads=windows |
| test "x$enable_shared" = xyes && create_import_lib=yes |
| AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer" |
| ;; |
| *) |
| AC_MSG_RESULT([Null]) |
| AC_MSG_WARN([The host being compiled for is not supported.]) |
| AC_MSG_WARN([The library may compile but will not function in any useful manner.]) |
| backend="null" |
| poll=posix |
| threads="posix" |
| ;; |
| esac |
| |
| if test "x$poll" = xposix; then |
| AC_DEFINE([POLL_POSIX], [1], [Define to 1 if using the POSIX poll() implementation.]) |
| AC_CHECK_TYPES([nfds_t], [], [], [[#include <poll.h>]]) |
| AC_CHECK_FUNCS([pipe2]) |
| elif test "x$poll" = xwindows; then |
| AC_DEFINE([POLL_WINDOWS], [1], [Define to 1 if using the Windows poll() implementation.]) |
| else |
| AC_MSG_ERROR([Unknown poll implementation]) |
| fi |
| |
| if test "x$threads" = xposix; then |
| AC_DEFINE([THREADS_POSIX], [1], [Define to 1 if using POSIX threads.]) |
| AC_SUBST(THREAD_CFLAGS, [-pthread]) |
| dnl Android Linux and Darwin provide pthread functions directly in libc |
| dnl glibc also provides some pthread functions directly, so search for a thread-specific function |
| AC_SEARCH_LIBS([pthread_key_create], [pthread], [AC_SUBST(THREAD_LIBS, [-lpthread])], [], []) |
| elif test "x$threads" = xwindows; then |
| AC_DEFINE([THREADS_WINDOWS], [1], [Define to 1 if using Windows threads.]) |
| else |
| AC_MSG_ERROR([Unknown threads implementation]) |
| fi |
| |
| case $backend in |
| darwin) |
| AC_CHECK_FUNCS([pthread_threadid_np]) |
| LIBS="${LIBS} -lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation" |
| ;; |
| haiku) |
| LIBS="${LIBS} -lbe" |
| ;; |
| linux) |
| AC_SEARCH_LIBS([clock_gettime], [rt], [], [], []) |
| AC_CHECK_FUNCS([pthread_setname_np]) |
| AC_ARG_ENABLE([udev], |
| [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended) [default=yes]])], |
| [use_udev=$enableval], [use_udev=yes]) |
| if test "x$use_udev" = xyes; then |
| dnl system has udev. use it or fail! |
| AC_CHECK_HEADER([libudev.h], [], [AC_MSG_ERROR([udev support requested but libudev header not installed])]) |
| AC_CHECK_LIB([udev], [udev_new], [], [AC_MSG_ERROR([udev support requested but libudev not installed])]) |
| else |
| AC_CHECK_HEADERS([asm/types.h]) |
| AC_CHECK_HEADER([linux/netlink.h], [], [AC_MSG_ERROR([Linux netlink header not found])]) |
| AC_CHECK_HEADER([sys/socket.h], [], [AC_MSG_ERROR([Linux socket header not found])]) |
| fi |
| ;; |
| sunos) |
| LIBS="${LIBS} -ldevinfo" |
| ;; |
| windows) |
| AC_CHECK_TYPES([struct timespec], [], [], [[#include <time.h>]]) |
| AC_DEFINE([_WIN32_WINNT], [_WIN32_WINNT_VISTA], [Define to the oldest supported Windows version.]) |
| LT_LDFLAGS="${LT_LDFLAGS} -avoid-version -Wl,--add-stdcall-alias" |
| ;; |
| *) |
| dnl no special handling required |
| ;; |
| esac |
| |
| dnl headers not available on all platforms but required on others |
| AC_CHECK_HEADERS([sys/time.h]) |
| |
| dnl the clock_gettime() function needs certain clock IDs defined |
| AC_CHECK_FUNCS([clock_gettime], [have_clock_gettime=yes], [have_clock_gettime=]) |
| if test "x$have_clock_gettime" = xyes; then |
| AC_CHECK_DECL([CLOCK_REALTIME], [], [AC_MSG_ERROR([C library headers missing definition for CLOCK_REALTIME])], [[#include <time.h>]]) |
| AC_CHECK_DECL([CLOCK_MONOTONIC], [], [AC_MSG_ERROR([C library headers missing definition for CLOCK_MONOTONIC])], [[#include <time.h>]]) |
| elif test "x$backend" != xdarwin && test "x$backend" != xwindows; then |
| AC_MSG_ERROR([clock_gettime() is required on this platform]) |
| fi |
| |
| dnl timerfd support |
| if test "x$backend" = xlinux || test "x$backend" = xsunos; then |
| AC_ARG_ENABLE([timerfd], |
| [AS_HELP_STRING([--enable-timerfd], [use timerfd for timing [default=auto]])], |
| [use_timerfd=$enableval], |
| [use_timerfd=auto]) |
| if test "x$use_timerfd" != xno; then |
| AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=yes], [timerfd_h=]) |
| if test "x$timerfd_h" = xyes; then |
| AC_CHECK_DECLS([TFD_NONBLOCK, TFD_CLOEXEC], [timerfd_h_ok=yes], [timerfd_h_ok=], [[#include <sys/timerfd.h>]]) |
| if test "x$timerfd_h_ok" = xyes; then |
| AC_CHECK_FUNC([timerfd_create], [timerfd_ok=yes], [timerfd_ok=]) |
| if test "x$timerfd_ok" = xyes; then |
| AC_DEFINE([HAVE_TIMERFD], [1], [Define to 1 if the system has timerfd functionality.]) |
| elif test "x$use_timerfd" = xyes; then |
| AC_MSG_ERROR([timerfd_create() function not found; glibc 2.9+ required]) |
| fi |
| elif test "x$use_timerfd" = xyes; then |
| AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required]) |
| fi |
| elif test "x$use_timerfd" = xyes; then |
| AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required]) |
| fi |
| fi |
| AC_MSG_CHECKING([whether to use timerfd for timing]) |
| if test "x$use_timerfd" = xno; then |
| AC_MSG_RESULT([no (disabled by user)]) |
| elif test "x$timerfd_h" != xyes; then |
| AC_MSG_RESULT([no (header not available)]) |
| elif test "x$timerfd_h_ok" != xyes; then |
| AC_MSG_RESULT([no (header not usable)]) |
| elif test "x$timerfd_ok" != xyes; then |
| AC_MSG_RESULT([no (functions not available)]) |
| else |
| AC_MSG_RESULT([yes]) |
| fi |
| fi |
| |
| dnl Message logging |
| AC_ARG_ENABLE([log], |
| [AS_HELP_STRING([--disable-log], [disable all logging])], |
| [log_enabled=$enableval], |
| [log_enabled=yes]) |
| if test "x$log_enabled" != xno; then |
| AC_DEFINE([ENABLE_LOGGING], [1], [Define to 1 to enable message logging.]) |
| fi |
| |
| AC_ARG_ENABLE([debug-log], |
| [AS_HELP_STRING([--enable-debug-log], [start with debug message logging enabled [default=no]])], |
| [debug_log_enabled=$enableval], |
| [debug_log_enabled=no]) |
| if test "x$debug_log_enabled" != xno; then |
| AC_DEFINE([ENABLE_DEBUG_LOGGING], [1], [Define to 1 to start with debug message logging enabled.]) |
| fi |
| |
| AC_ARG_ENABLE([system-log], |
| [AS_HELP_STRING([--enable-system-log], [output logging messages to the systemwide log, if supported by the OS [default=no]])], |
| [system_log_enabled=$enableval], |
| [system_log_enabled=no]) |
| if test "x$system_log_enabled" != xno; then |
| AC_DEFINE([USE_SYSTEM_LOGGING_FACILITY], [1], [Define to 1 to output logging messages to the systemwide log.]) |
| if test "x$backend" != xwindows && test "x$is_android_linux" != xyes; then |
| dnl Check if syslog is available in standard C library |
| AC_CHECK_HEADER([syslog.h], [syslog_h=yes], [syslog_h=]) |
| if test "x$syslog_h" = xyes; then |
| AC_CHECK_FUNCS([syslog]) |
| fi |
| fi |
| fi |
| |
| dnl Examples build |
| AC_ARG_ENABLE([examples-build], |
| [AS_HELP_STRING([--enable-examples-build], [build example applications [default=no]])], |
| [build_examples=$enableval], |
| [build_examples=no]) |
| if test "x$build_examples" != xno; then |
| dnl sigaction needed for some example programs |
| AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=]) |
| fi |
| |
| dnl Tests build |
| AC_ARG_ENABLE([tests-build], |
| [AS_HELP_STRING([--enable-tests-build], [build test applications [default=no]])], |
| [build_tests=$enableval], |
| [build_tests=no]) |
| |
| AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != xno]) |
| AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != xno]) |
| AM_CONDITIONAL([CREATE_IMPORT_LIB], [test "x$create_import_lib" = xyes]) |
| AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = xyes]) |
| AM_CONDITIONAL([OS_DARWIN], [test "x$backend" = xdarwin]) |
| AM_CONDITIONAL([OS_HAIKU], [test "x$backend" = xhaiku]) |
| AM_CONDITIONAL([OS_LINUX], [test "x$backend" = xlinux]) |
| AM_CONDITIONAL([OS_NETBSD], [test "x$backend" = xnetbsd]) |
| AM_CONDITIONAL([OS_NULL], [test "x$backend" = xnull]) |
| AM_CONDITIONAL([OS_OPENBSD], [test "x$backend" = xopenbsd]) |
| AM_CONDITIONAL([OS_SUNOS], [test "x$backend" = xsunos]) |
| AM_CONDITIONAL([OS_WINDOWS], [test "x$backend" = xwindows]) |
| AM_CONDITIONAL([POLL_POSIX], [test "x$poll" = xposix]) |
| AM_CONDITIONAL([POLL_WINDOWS], [test "x$poll" = xwindows]) |
| AM_CONDITIONAL([THREADS_POSIX], [test "x$threads" = xposix]) |
| AM_CONDITIONAL([THREADS_WINDOWS], [test "x$threads" = xwindows]) |
| AM_CONDITIONAL([USE_UDEV], [test "x$use_udev" = xyes]) |
| |
| EXTRA_CFLAGS= |
| |
| dnl The -Wcast-function-type warning causes a flurry of warnings when compiling |
| dnl Windows with GCC 8 or later because of dynamically loaded functions |
| if test "x$backend" = xwindows; then |
| saved_CFLAGS="${CFLAGS}" |
| CFLAGS="-Werror -Wcast-function-type" |
| AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], |
| [EXTRA_CFLAGS="-Wno-cast-function-type"], |
| []) |
| CFLAGS="${saved_CFLAGS}" |
| fi |
| |
| AM_CFLAGS="${AM_CFLAGS} -Wall -Wextra -Wshadow -Wunused -Wwrite-strings -Werror=format-security -Werror=implicit-function-declaration -Werror=implicit-int -Werror=init-self -Werror=missing-prototypes -Werror=strict-prototypes -Werror=undef -Werror=uninitialized ${EXTRA_CFLAGS}" |
| AC_SUBST(AM_CFLAGS) |
| |
| AM_CXXFLAGS="${AM_CFLAGS} -Wmissing-declarations" |
| AC_SUBST(AM_CXXFLAGS) |
| |
| AC_SUBST(LT_LDFLAGS) |
| |
| dnl set name of html output directory for doxygen |
| AC_SUBST(DOXYGEN_HTMLDIR, [api-1.0]) |
| |
| AC_CONFIG_FILES([libusb-1.0.pc]) |
| AC_CONFIG_FILES([Makefile]) |
| AC_CONFIG_FILES([libusb/Makefile]) |
| AC_CONFIG_FILES([examples/Makefile]) |
| AC_CONFIG_FILES([tests/Makefile]) |
| AC_CONFIG_FILES([doc/Makefile]) |
| AC_CONFIG_FILES([doc/doxygen.cfg]) |
| AC_OUTPUT |
