src/android_internal/BUILD.gn

# Copyright (C) 2018 The Android Open Source Project
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("../../gn/perfetto.gni")

source_set("headers") {
  deps = [
    "../../gn:default_deps",
  ]
  sources = [
    "health_hal.h",
  ]
}

# This target proxies calls to Android internal libraries that are not part of
# the NDK. See README.md.
source_set("android_internal") {
  visibility = [ "//:libperfetto_android_internal" ]
  deps = [
    ":headers",
    "../../gn:default_deps",
  ]
  if (perfetto_build_with_android) {
    sources = [
      "health_hal.cc",
    ]
    libs = [
      "android.hardware.health@2.0",
      "base",
      "log",
      "hwbinder",
      "hidlbase",
      "hidltransport",
      "utils",
    ]
  }

  # This target should never depend on any other perfetto target to avoid ODR
  # violation by doubly linking code in two .so(s) loaded in the same exe.
  assert_no_deps = [
    "//src/base/*",
    "//src/tracing/*",
    "//include/*",
  ]
}