src/tracing/ipc/producer/BUILD.gn

# Copyright (C) 2020 The Android Open Source Project
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("../../../../gn/perfetto.gni")
import("../../../../gn/perfetto_component.gni")

assert(enable_perfetto_ipc)

# Posix specialization of the tracing library for Linux / Android / Mac.
# Provides an IPC transport over a UNIX socket for the producer interface.
source_set("producer") {
  public_deps = [
    "../../../../include/perfetto/ext/tracing/core",
    "../../../../include/perfetto/ext/tracing/ipc",
    "../../../../include/perfetto/tracing",
    "../../../../protos/perfetto/ipc",
  ]
  sources = [
    "producer_ipc_client_impl.cc",
    "producer_ipc_client_impl.h",
  ]
  deps = [
    "..:common",
    "../../../../gn:default_deps",
    "../../../base",
    "../../../base:version",
    "../../core",
  ]
  if (perfetto_component_type == "static_library") {
    deps += [ "../../../ipc:perfetto_ipc" ]
  } else {
    deps += [ "../../../ipc:client" ]
  }
}

# Relay port client implementation, used by the relay service.
source_set("relay") {
  public_deps = [ "../../../../protos/perfetto/ipc" ]
  sources = [
    "relay_ipc_client.cc",
    "relay_ipc_client.h",
  ]
  deps = [
    "..:common",
    "../../../../gn:default_deps",
  ]
  if (perfetto_component_type == "static_library") {
    deps += [ "../../../ipc:perfetto_ipc" ]
  } else {
    deps += [ "../../../ipc:client" ]
  }
}